Mozaic script to record CC, PW,.. as notes and back to normal(1.0 beta)

mbncp

// CC2Note 1.0.0  -  Mozaic 1.3.9

@OnLoad
  CC_64 = 0 // use midi note 0 = lowest note = C-2 (cubasis,drambo) or C-1(aum, atom)
// for continuous CC it would be better to use a few notes, using 1,2,3,4,5,1,2,3,4,5...
  CC_1 = 1
  // for pitch bend we need a 14 bit value, so we use 2 notes
  PITCH_1 = 2
  PITCH_2 = 3

  // for continuous CC we need a note off time
  CC_NoteDuration = 64  // 1/64 use 64, 1/32 use 32, .., 1 Beat use 1
  // make sure to set QUANT to OFF in atom when recording, unless that's what you want
  SetShortName {CC-2-N}
@End

@OnMidiInput
  if MIDICommand = 0xB0 // CC
    if MIDIByte2 = 64 // Pedal
       SendMIDIOut 0x90 | MIDIChannel , CC_64, MIDIByte3
    elseif MIDIByte2 = 1 // ModWheel
       v = MIDIByte3
       Inc v, 127
       SendMIDIOut 0x90 | MIDIChannel , CC_1, v
       SendMIDIOut 0x80 | MIDIChannel, CC_1, 0, Round(QuarterNote*4 / CC_NoteDuration)
    else
      SendMIDIThru
    endif
  elseif MIDICommand = 0xE0 // Pitch Bend
     v = MIDIByte2
     Inc v, 127
     SendMIDIOut 0x90 | MIDIChannel , PITCH_1, v
     v = MIDIByte3
     Inc v, 127
     SendMIDIOut 0x90 | MIDIChannel , PITCH_2, v
     SendMIDIOut 0x80 | MIDIChannel , PITCH_1, , Round(QuarterNote*4 / CC_NoteDuration)
     SendMIDIOut 0x80 | MIDIChannel , PITCH_2, , Round(QuarterNote*4 / CC_NoteDuration)
  else
    SendMIDIThru
  endif
@End

mbncp

// Note2CC 1.0.0  -  Mozaic 1.3.9

@OnLoad
 // TODO you can add any other CC // it needs some extra coding
  CC_64 = 0 // use midi note 0 = lowest note = C-2 (Drambo, cubasis) or C-1(aum, atom)
// for continuous CC it would be better to use a few notes, using 1,2,3,4,5,1,2,3,4,5...
  CC_1 = 1
  // for pitch bend we need a 14 bit value, so we use 2 notes
  PITCH_1 = 2
  PITCH_2 = 3
  LAST_CC = 3
// End of TODO
  SetShortName {N-2-CC}
  // some pitch wheel flags
  p1 = -1
  p2 = -1
@End

@OnMidiInput
  if MIDICommand = 0x90 // Note On
    if MIDIByte2 = CC_64 // Pedal
       SendMIDIOut 0xB0 | MIDIChannel , 64, 127
    elseif MIDIByte2 = CC_1 // ModWheel
       v = MIDIByte3
       Dec v, 0
       If v = 126
         v = 127
       endif
       SendMIDIOut 0xB0 | MIDIChannel , CC_1, v
    elseif MIDIByte2 = PITCH_1
      p1 = MIDIByte3
      if p1 < 127
        DEc p1, 0
      endif
      if p2 >= 0
        SendMIDIOut 0xE0 | MIDIChannel, p1, p2
        p1 = -1
        p2 = -1
      endif
    elseif MIDIByte2 = PITCH_2
      p2 = MIDIByte3
      if p2 < 127
        DEc p2, 0
      endif
      if p1 >= 0
        SendMIDIOut 0xE0 | MIDIChannel, p1, p2
        p1 = -1
        p2 = -1
      endif
    else
      SendMIDIThru
    endif
  elseif MIDICommand = 0x80 // note off
    if MIDIByte2 = CC_64 // Pedal
      SendMIDIOut 0xB0 | MIDIChannel, 64, 0
    elseif MIDIByte2 <= LAST_CC
      exit // no use of note off for other CC
    else    
      SendMIDIThru
    endif
  else
    SendMIDIThru
  endif
@End

_ki

@mbncp Nice and usefull idea for a script. Since the normal midi notes run through, one script can be used ‚before‘ sendeing to record the data in Atom converting CC-1 and PitchBend to low notes. And the second script is placed ‚after‘ Atom to re-generate CC-1 / PitchBend before driving an instrument.

Just some minor remarks for polishing:

• In OnLoad add SetShortName {CC-2-N} and SetShortName {N-2-CC} to add an icon name that also helps identifying the scripts in AUMs midi matrix.
• Add a @Description block at the top, containg the script‘s name and a short usage instruction. Then in each OnLoad add a ShowLayout 4 to show this description when loading the script.

It would be cool if you also could publish these to PatchStorage. I suggest combining both into a zip since they belong together and diffferent versions of each could be problematic.

Poppadocrock

No way, I’ve been wanting a way to record automation in Mozaic. It be cool if you took @_ki notes and put on Patchstorage. Thanks for the great work.

_ki

@Poppadocrock The recording / replay takes place in Atom or Atom ² , not in the script itself.

These handy scripts convert ModWheel/PitchBend to low notes to be recorded in addition to the normal notes. For playback playback, feed the recording into the second script to convert the low notes back to ModdWheel/PitchBend and passing on the normal notes

mbncp

@_ki
I did this just to try the concept. The scripts are badly written, making it difficult for the end user to add or remove a "CC".
I don't think I will go any further with this, though it could be interesting in a specific situation.
If cc recording wouldn't come on atom2, it would be something else, but I don't mind waiting a bit longer, and have an integrated solution.

Poppadocrock

@_ki said:
@Poppadocrock The recording / replay takes place in Atom or Atom ² , not in the script itself.

These handy scripts convert ModWheel/PitchBend to low notes to be recorded in addition to the normal notes. For playback playback, feed the recording into the second script to convert the low notes back to ModdWheel/PitchBend and passing on the normal notes

Oh, ok, my mistake, I thought I was off about something because @wim told me recently that would be very difficult and tedious, or something to that effect.

Recently realized MidiMixer has 3 custom CC’s you can draw in automation.